Arduino内置教程-USB-键盘注销

键盘注销

• 这个例子历，当你的Leonardo, Micro 或者 Due开发板上的pin2下拉到地时，你可以用键盘库来注销在你电脑上的使用会话控制。这个程序模仿两三个按键按一定的顺序按下，并且一小段延迟后自动松开。

• 注意:当你用 Keyboard.print() 命令时，Arduino会接管你的电脑键盘！为了确保你没有失去对电脑的控制同时运行这个函数，确定在你调用 Keyboard.print()前，启动一个可靠的控制系统。这个程序被设计成只有在一个引脚下拉到地才能发送键盘命令。

硬件要求

• Arduino Leonardo, Micro, or Due开发板
• 按键
• 连接线
• 面包板

电路

图由Fritzing软件绘制

原理图

样例代码

• 在你更新代码到你开发板之前，确保分配正确的OS，你当前在平台上使用的的变量。

• 当程序正在运行，按下按键将会连接pin2到地，而开发板将会发送注销顺序到USB连接的电脑。

/*
  Keyboard logout

 This sketch demonstrates the Keyboard library.

 When you connect pin 2 to ground, it performs a logout.
 It uses keyboard combinations to do this, as follows:

 On Windows, CTRL-ALT-DEL followed by ALT-l
 On Ubuntu, CTRL-ALT-DEL, and ENTER
 On OSX, CMD-SHIFT-q

 To wake: Spacebar.

 Circuit:
 * Arduino Leonardo or Micro
 * wire to connect D2 to ground.

 created 6 Mar 2012
 modified 27 Mar 2012
 by Tom Igoe

 This example is in the public domain

 http://www.arduino.cc/en/Tutorial/KeyboardLogout
 */

#define OSX 0
#define WINDOWS 1
#define UBUNTU 2

#include "Keyboard.h"

// change this to match your platform:
int platform = OSX;

void setup() {
  // make pin 2 an input and turn on the
  // pullup resistor so it goes high unless
  // connected to ground:
  pinMode(2, INPUT_PULLUP);
  Keyboard.begin();
}

void loop() {
  while (digitalRead(2) == HIGH) {
    // do nothing until pin 2 goes low
    delay(500);
  }
  delay(1000);

  switch (platform) {
    case OSX:
      Keyboard.press(KEY_LEFT_GUI);
      // Shift-Q logs out:
      Keyboard.press(KEY_LEFT_SHIFT);
      Keyboard.press('Q');
      delay(100);
      Keyboard.releaseAll();
      // enter:
      Keyboard.write(KEY_RETURN);
      break;
    case WINDOWS:
      // CTRL-ALT-DEL:
      Keyboard.press(KEY_LEFT_CTRL);
      Keyboard.press(KEY_LEFT_ALT);
      Keyboard.press(KEY_DELETE);
      delay(100);
      Keyboard.releaseAll();
      //ALT-l:
      delay(2000);
      Keyboard.press(KEY_LEFT_ALT);
      Keyboard.press('l');
      Keyboard.releaseAll();
      break;
    case UBUNTU:
      // CTRL-ALT-DEL:
      Keyboard.press(KEY_LEFT_CTRL);
      Keyboard.press(KEY_LEFT_ALT);
      Keyboard.press(KEY_DELETE);
      delay(1000);
      Keyboard.releaseAll();
      // Enter to confirm logout:
      Keyboard.write(KEY_RETURN);
      break;
  }

  // do nothing:
  while (true);
}

[Get Code]
更多

• Keyboard.write()
• Keyboard.print()
• Keyboard.println()
• KeyboardLogout - 利用按键命令注销当前使用者
• KeyboardMessage - 当一个按键被按下，发送一个文本字符串。
• KeyboardReprogram - 在Arduino IDE上打开一个新窗口，用简单的跑马灯程序重新编译Leonardo
• KeyboardSerial - 从串口里读取一个字节，然后返回一个键值。
• KeyboardAndMouseControl - 在一个程序里示范鼠标和键盘命令
• ButtonMouseControl - 通过5个按键控制光标行动
• JoystickMouseControl - 当按键被按下时，通过一个操纵杆来控制电脑光标的行动