Arduino教程学习A17-Arduino连接TTP229B电容触摸模块

Arduino连接TTP229B电容触摸模块



新买一个TTP229B的16键触摸模块，黑心淘宝居然没给对PDF也没有借鉴的驱动代码，于是去官网下载了个pdf看时序图模仿了一个。

先上pdf文件

TTP229-BSF_V1.1_EN.pdf
网盘下载http://pan.baidu.com/s/1dExdYV3


这个是TTP-229B(SSOP-28)的PDF，来自官网

http://www.tontek.com.tw/031-1-1.asp?p3id=20141007154716



硬件部分：

首先看文档调好跳线，其中1脚对应TP0,2脚对应TP1如此类推，把1/2/3/4/5跳线跳上，即TP0-TP4均为低电平0

含义如下：

TP0=0,TP1=0：SDA高电平激活

HT74M%0Q}9XI%F}B9M315XB.png

2015-6-29 16:01 上传
(30.79 KB)



TP2=0：16按键全使用

TP3=0,TP4=0：所有按键Multi Key，即可以同时按下所有按键。

V{~A%Q@0K_~LUMO6OG7G]PJ.png

2015-6-29 16:01 上传
(120.92 KB)





下面是跳好跳线的图片

QQ图片20150629155348.jpg

2015-6-29 15:54 上传
(161.21 KB)





一定要把模块的1-5跳线跳好，否则下面代码不能正常读取。

3_Q~6OHHB4EX`HG(O[JO2`N.png

2015-6-29 16:28 上传
(366.15 KB)





两个代码，一个是单独读一个按键，一个一次读完所有按键





一个是单独读一个按键

ARDUINO

int SCLPin = A5, SDOPin = A4;   //SCL接A5，SDO接A4，非IIC，可以随意移动引脚接法
boolean h = 0, oldh = 0;
void setup()
{
  Serial.begin(9600);
  pinMode(SCLPin , OUTPUT);   //时钟端输出
}
 
boolean ttp229single(int pin)
{
  boolean DATA = 0;
  pinMode(SDOPin , OUTPUT);
  digitalWrite(SDOPin, HIGH);
  delayMicroseconds(93);    //DV时间93us
  digitalWrite(SDOPin, LOW);
  delayMicroseconds(10);    //Tw时间10us
  pinMode(SDOPin , INPUT);
  for (int i = 0; i < 16; i++)
  {
    digitalWrite(SCLPin, HIGH);
    digitalWrite(SCLPin, LOW);
    if (i == pin-1)
    {
      DATA = digitalRead(SDOPin);    //读取数据
    }
  }
  delay(2);    //Tout时间2ms
  return DATA;
}
 
void loop()
{
  h = ttp229single(3);    //本例读了写着3数字的触摸键（TP2）
 
  if (h != oldh)    //数据改变的时候输出h
  {
    Serial.println(h);
    oldh = h;
    delay(40);      //满足pdf的T_resp(for 16-KEYS)时间32ms
  }
}




一个一次读完所有按键

ARDUINO

int SCLPin = A5, SDOPin = A4;
unsigned int h = 0, oldh = 0;
void setup()
{
  Serial.begin(9600);
  pinMode(SCLPin , OUTPUT);   //时钟端输出
}
 
unsigned int ttp229()     //一次读完TTP229所有按键
{
  unsigned int DATA = 0;
  pinMode(SDOPin , OUTPUT);
  digitalWrite(SDOPin, HIGH);
  delayMicroseconds(93);
  digitalWrite(SDOPin, LOW);
  delayMicroseconds(10);
  pinMode(SDOPin , INPUT);
  for (int i = 0; i < 16; i++)
  {
    digitalWrite(SCLPin, HIGH);
    digitalWrite(SCLPin, LOW);
    DATA |= digitalRead(SDOPin) << i;
  }
  delay(2);
  return DATA&0xFFFF;
}
 
void loop()
{
  h = ttp229();
  if (h != oldh)
  {
    Serial.println(h, BIN);
    oldh = h;
    delay(40);
  }
}




进阶阅读：代码与时序图关系简述

U}YG4OMAQ6H83DV[7[B1YWM.png

2015-6-29 16:23 上传
(238.95 KB)


via - 极客工坊

标签: Arduino教程