Arduino内置教程-传感器-Ping

Ping 超声波测距仪

• SEN136B5B是一款来自Seeedstudio（矽递公司）的超声波测距仪。它测量传感器前面最近物体的距离（从3cm到400cm）。它通过发出一个超声波突发脉冲，并在它遇到物体反弹时收到回音。它用超声波测量障碍物距离。Arduino或者Genuino开发板发送一个短脉冲来启动这个测量器，然后在同样的引脚用 pulseIn()函数来接受一个脉冲。第二个脉冲持续的时间就是超声波到达物体并且又返回传感器的时间。用声音的速度来把这个时间换算成距离。

硬件要求

• Arduino or Genuino 开发板
• SEN136B5B 超声波测距仪
• 连接线

电路

SEN136B5B的5V引脚连接到开发板的5V引脚，而GND引脚也连到GND引脚，SIG（signal）引脚连接到板上的数字引脚pin7.

图由 Fritzing 软件绘制。

原理图

样例代码

/* Ping))) Sensor

   This sketch reads a PING))) ultrasonic rangefinder and returns the
   distance to the closest object in range. To do this, it sends a pulse
   to the sensor to initiate a reading, then listens for a pulse
   to return.  The length of the returning pulse is proportional to
   the distance of the object from the sensor.

   The circuit:
    * +V connection of the PING))) attached to +5V
    * GND connection of the PING))) attached to ground
    * SIG connection of the PING))) attached to digital pin 7

   http://www.arduino.cc/en/Tutorial/Ping

   created 3 Nov 2008
   by David A. Mellis
   modified 30 Aug 2011
   by Tom Igoe

   This example code is in the public domain.

 */

// this constant won't change.  It's the pin number
// of the sensor's output:
const int pingPin = 7;

void setup() {
  // initialize serial communication:
  Serial.begin(9600);
}

void loop() {
  // establish variables for duration of the ping,
  // and the distance result in inches and centimeters:
  long duration, inches, cm;

  // The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
  // Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(5);
  digitalWrite(pingPin, LOW);

  // The same pin is used to read the signal from the PING))): a HIGH
  // pulse whose duration is the time (in microseconds) from the sending
  // of the ping to the reception of its echo off of an object.
  pinMode(pingPin, INPUT);
  duration = pulseIn(pingPin, HIGH);

  // convert the time into a distance
  inches = microsecondsToInches(duration);
  cm = microsecondsToCentimeters(duration);

  Serial.print(inches);
  Serial.print("in, ");
  Serial.print(cm);
  Serial.print("cm");
  Serial.println();

  delay(100);
}

long microsecondsToInches(long microseconds) {
  // According to Parallax's datasheet for the PING))), there are
  // 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
  // second).  This gives the distance travelled by the ping, outbound
  // and return, so we divide by 2 to get the distance of the obstacle.
  // See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
  return microseconds / 74 / 2;
}

long microsecondsToCentimeters(long microseconds) {
  // The speed of sound is 340 m/s or 29 microseconds per centimeter.
  // The ping travels out and back, so to find the distance of the
  // object we take half of the distance travelled.
  return microseconds / 29 / 2;
}

[Get Code]

更多

• pinMode()
• delayMicroseconds()
• pulseIn()
• digitalWrite()
• return
• serial.begin()
• serial.print()
• Knock: 通过一个压电元件来侦察敲击
• Memsic2125: 2轴加速计
• Ping: 通过一个超声波测距仪来侦察物品